/* Maxima source code for the computations of the dimensions of 			*/
/* the (G x G) x Z_2 - invariants in the alternating/symmetric triple products.	*/
/* By Yuji Ohta (2022)									*/

/* constants */
alpha:(1+sqrt(5))/2;
beta:(1-sqrt(5))/2;

/* size of the conjugacy classes */
n:matrix([1,1,30,20,20,12,12,12,12]);
c:transpose(n);
N:c.transpose(c);

/* character table (of \chi_V(g)) */
X:matrix(
[1,1,1,1,1,1,1,1,1],
[2,-2,0,-1,1,-beta,-alpha,beta,alpha],
[2,-2,0,-1,1,-alpha,-beta,alpha,beta],
[3,3,-1,0,0,alpha,beta,alpha,beta],
[3,3,-1,0,0,beta,alpha,beta,alpha],
[4,4,0,1,1,-1,-1,-1,-1],
[4,-4,0,1,-1,-1,-1,1,1],
[5,5,1,-1,-1,0,0,0,0],
[6,-6,0,0,0,1,1,-1,-1]);

/* XX: matrix whose (i,j)-entry = \sum_p \chi_{A_p x A_p}(c_i,c_j) = \sum_p \chi_{A_p}(c_i)*\chi_{A_p}(c_j) */
tX:transpose(X);
XX:tX.X;

/* table of \chi_V(g^2) */
Y:matrix(
[1,1,1,1,1,1,1,1,1],
[2,2,-2,-1,-1,-alpha,-beta,-alpha,-beta],
[2,2,-2,-1,-1,-beta,-alpha,-beta,-alpha],
[3,3,3,0,0,beta,alpha,beta,alpha],
[3,3,3,0,0,alpha,beta,alpha,beta],
[4,4,4,1,1,-1,-1,-1,-1],
[4,4,-4,1,1,-1,-1,-1,-1],
[5,5,5,-1,-1,0,0,0,0],
[6,6,-6,0,0,1,1,1,1]);

/* YY: matrix whose (i,j)-entry = \sum_p \chi_{A_p x A_p}(c_i^2,c_j^2) = \sum_p \chi_{A_p}(c_i^2)*\chi_{A_p}(c_j^2) */
tY:transpose(Y);
YY:tY.Y;

/* table of \chi_V(g^3) */
Z:matrix(
[1,1,1,1,1,1,1,1,1],
[2,-2,0,2,-2,-alpha,-beta,alpha,beta],
[2,-2,0,2,-2,-beta,-alpha,beta,alpha],
[3,3,-1,3,3,beta,alpha,beta,alpha],
[3,3,-1,3,3,alpha,beta,alpha,beta],
[4,4,0,4,4,-1,-1,-1,-1],
[4,-4,0,4,-4,-1,-1,1,1],
[5,5,1,5,5,0,0,0,0],
[6,-6,0,6,-6,1,1,-1,-1]);

/* ZZ: matrix whose (i,j)-entry = \sum_p \chi_{A_p x A_p}(c_i^3,c_j^3) = \sum_p \chi_{A_p}(c_i^3)*\chi_{A_p}(c_j^3) */
tZ:transpose(Z);
ZZ:tZ.Z;

/* (matrix).j: take sum in each row,  i.(matrix): take sum in each column */
i:matrix([1,1,1,1,1,1,1,1,1]);
j:transpose(i);
order:i.c;

/* characters of triple products and G x G invariants */
T1:(i.(N*XX*XX*XX)).j; /* \sum_{g,h} \chi_W(g,h)^3 */
T2:(i.(N*YY*XX)).j;	/* \sum_{g,h} \chi_W(g^2,h^2)\chi_W(g,h) */
T3:(i.(N*ZZ)).j;	/* \sum_{g,h} \chi_W(g^3,h^3) */
Total1:expand((1/6)*(T1-3*T2+2*T3)/(order^2)); 
TotalS1:expand((1/6)*(T1+3*T2+2*T3)/(order^2));

xx:i.X; /* \sum_i \chi_{A_i}(g) */
xx2:i.(X*X); /* \sum_i \chi_{A_i}(g)^2 */
yy:i.Y; /* \sum_i \chi_{A_i}(g^2) */
zz:i.Z; /* \sum_i \chi_{A_i}(g^3) */

tt1:(n*xx*xx*xx).j; /* \sum_g (\sum_i \chi_{A_i}(g))^3 */
tt2:(n*xx2*xx).j; /* \sum_g (\sum_i \chi_{A_i}(g)^2)(\sum_i \chi_{A_i}(g)) */
tt3:(n*zz).j; /* \sum_g (\sum_i \chi_{A_i}(g^3)) */
Total2:expand((1/6)*order*(tt1-3*tt2+2*tt3)/(order^2));
TotalS2:expand((1/6)*order*(tt1+3*tt2+2*tt3)/(order^2));


/* dimensions of the (G x G) x Z_2 invariant part */
Alt_inv:(Total1+Total2)/2; /* alternating product */
Sym_inv:(TotalS1+TotalS2)/2; /* symmetric product */